You are viewing an old version of this page. View the current version.

Compare with Current View Page History

« Previous Version 7 Next »

Obavijest je namijenjena za visoka učilišta koja ne koriste pretpostavljeni XSL predložak za vrstu dokumenta 15 - Diploma, nego imaju prilagođeni XSL predložak diplome. To su ona visoka učilišta koja u prozoru Izgled dokumenta na jeziku za VU imaju definiran zapis o proizvoljnom predlošku. Prilagođeni predložak održava informatička služba visokog učilišta.

Izmjene u pretpostavljenom predlošku vrste dokumenta 15 - Diploma

Pretpostavljeni predložak se može naći u prozoru Izgled dokumenta na jeziku.

Dodan ispis OIB-a

Na 386. liniji pretpostavljenog predloška dodan je blok za ispis OIB-a studenta. Navedeni blok se može iskoristiti za ispis OIB-a na proizvoljnom mjestu u prilagođenom predlošku dokumenta visokog učilišta.

OIB
      <fo:block xsl:use-attribute-sets="attset-normalTekst">
         <xsl:text>(</xsl:text>
         <xsl:choose>
            <xsl:when test="$lang='hr'">
               <xsl:text>OIB: </xsl:text>
            </xsl:when>
            <xsl:when test="$lang='en'">
               <xsl:text>PIN: </xsl:text>
            </xsl:when>
         </xsl:choose>
         <xsl:value-of select="student/oib" />
         <xsl:text>)</xsl:text>
      </fo:block>



Dodan ispis znanstvenog područja

Template definicija

Na 973. liniji pretpostavljenog predloška dodan je template za ispis podrucja. Navedeni template se može ukopirati u prilagođeni predložak kako bi se kasnije mogao iskoristiti za ispis na proizvojnom mjestu

Template definicija
    <!-- procedura za ispis znanstvenih podrucja    -->
   <xsl:template name="ispisZnanstvenoPodrucje">
      <xsl:param name="lang"/>
      <xsl:param name="spol"/>

      <xsl:choose>
         <xsl:when test="$lang='hr'">

            <xsl:choose>
                <!-- jednopredmetni studij ili dvopredmetni s istim znanstvenim podrucjem-->
                <xsl:when test="(count(studijskiProgram/smjerovi/smjer) = 1) or (studijskiProgram/smjerovi/smjer[1]/nazZnanstvenoPodrucje = studijskiProgram/smjerovi/smjer[2]/nazZnanstvenoPodrucje)">

                  <xsl:choose>
                     <xsl:when test="studijskiProgram/smjerovi/smjer[1]/vrstaZnanstvenoPodrucje = 1">
                        <xsl:text>u znanstvenom podru&#269;ju </xsl:text>
                        <xsl:value-of select="lower-case(studijskiProgram/smjerovi/smjer[1]/nazZnanstvenoPodrucjeGenitiv)" />
                     </xsl:when>
                     <xsl:otherwise>
                        <xsl:text>u </xsl:text>
                        <xsl:value-of select="lower-case(studijskiProgram/smjerovi/smjer[1]/nazZnanstvenoPodrucjeDativ)" />
                     </xsl:otherwise>
                  </xsl:choose>
                  
                  <xsl:text> </xsl:text>
                </xsl:when>
                <!-- dvopredmetni studiji s različitim znanstvenim područjima -->
                <xsl:otherwise>
                     <xsl:choose>
                        <xsl:when test="(studijskiProgram/smjerovi/smjer[1]/vrstaZnanstvenoPodrucje = 1) and (studijskiProgram/smjerovi/smjer[2]/vrstaZnanstvenoPodrucje = 1)">
                              <xsl:text>u znanstvenim podru&#269;jima </xsl:text>
                              <xsl:value-of select="lower-case(studijskiProgram/smjerovi/smjer[1]/nazZnanstvenoPodrucjeGenitiv)" />
                              <xsl:text> i </xsl:text>
                              <xsl:value-of select="lower-case(studijskiProgram/smjerovi/smjer[2]/nazZnanstvenoPodrucjeGenitiv)" />
                              <xsl:text> </xsl:text>
                        </xsl:when>

                        <xsl:when test="(studijskiProgram/smjerovi/smjer[1]/vrstaZnanstvenoPodrucje != 1) and (studijskiProgram/smjerovi/smjer[2]/vrstaZnanstvenoPodrucje != 1)">
                              <xsl:text>u </xsl:text>
                              <xsl:value-of select="lower-case(studijskiProgram/smjerovi/smjer[1]/nazZnanstvenoPodrucjeDativ)" />
                              <xsl:text> i u </xsl:text>
                              <xsl:value-of select="lower-case(studijskiProgram/smjerovi/smjer[2]/nazZnanstvenoPodrucjeDativ)" />
                              <xsl:text> </xsl:text>
                        </xsl:when>

                        <xsl:when test="(studijskiProgram/smjerovi/smjer[1]/vrstaZnanstvenoPodrucje = 1) and (studijskiProgram/smjerovi/smjer[2]/vrstaZnanstvenoPodrucje != 1)">
                              <xsl:text>u znanstvenom podru&#269;ju </xsl:text>
                              <xsl:value-of select="lower-case(studijskiProgram/smjerovi/smjer[1]/nazZnanstvenoPodrucjeGenitiv)" />
                              <xsl:text> i u </xsl:text>
                              <xsl:value-of select="lower-case(studijskiProgram/smjerovi/smjer[2]/nazZnanstvenoPodrucjeDativ)" />
                              <xsl:text> </xsl:text>
                        </xsl:when>

                        <xsl:when test="(studijskiProgram/smjerovi/smjer[1]/vrstaZnanstvenoPodrucje != 1) and (studijskiProgram/smjerovi/smjer[2]/vrstaZnanstvenoPodrucje = 1)">
                              <xsl:text>u </xsl:text>
                              <xsl:value-of select="lower-case(studijskiProgram/smjerovi/smjer[1]/nazZnanstvenoPodrucjeDativ)" />
                              <xsl:text> i u znanstvenom podru&#269;ju </xsl:text>
                              <xsl:value-of select="lower-case(studijskiProgram/smjerovi/smjer[2]/nazZnanstvenoPodrucjeGenitiv)" />
                              <xsl:text> </xsl:text>
                        </xsl:when>

                     </xsl:choose>
                </xsl:otherwise>
            </xsl:choose>

            <xsl:value-of select="document(concat('file:///', $konTekstDiploma))
                                                /konTekst/jezik[lang($lang)]
                                                /teStekao[contains(@spol,$spol)]" />
            <xsl:text> </xsl:text>
            
         </xsl:when>

         <xsl:when test="$lang='en'">

            <xsl:choose>
                <!-- jednopredmetni studij ili dvopredmetni s istim znanstvenim podrucjem-->
                <xsl:when test="(count(studijskiProgram/smjerovi/smjer) = 1) or (studijskiProgram/smjerovi/smjer[1]/nazZnanstvenoPodrucje = studijskiProgram/smjerovi/smjer[2]/nazZnanstvenoPodrucje)">

                  <xsl:choose>
                     <xsl:when test="studijskiProgram/smjerovi/smjer[1]/vrstaZnanstvenoPodrucje = 1">
                        <xsl:text>in the scientific field of </xsl:text>
                     </xsl:when>
                     <xsl:otherwise>
                        <xsl:text>in the field of  </xsl:text>
                     </xsl:otherwise>
                  </xsl:choose>

                  <xsl:value-of select="lower-case(studijskiProgram/smjerovi/smjer[1]/nazZnanstvenoPodrucje)" />
                  <xsl:text> </xsl:text>
                </xsl:when>
                <!-- dvopredmetni studiji s različitim znanstvenim područjima -->
                <xsl:otherwise>
                     <xsl:choose>
                        <xsl:when test="(studijskiProgram/smjerovi/smjer[1]/vrstaZnanstvenoPodrucje = 1) and (studijskiProgram/smjerovi/smjer[2]/vrstaZnanstvenoPodrucje = 1)">
                              <xsl:text>in scientific fields of </xsl:text>
                              <xsl:value-of select="lower-case(studijskiProgram/smjerovi/smjer[1]/nazZnanstvenoPodrucje)" />
                              <xsl:text> and </xsl:text>
                              <xsl:value-of select="lower-case(studijskiProgram/smjerovi/smjer[2]/nazZnanstvenoPodrucje)" />
                              <xsl:text> </xsl:text>
                        </xsl:when>

                        <xsl:when test="(studijskiProgram/smjerovi/smjer[1]/vrstaZnanstvenoPodrucje != 1) and (studijskiProgram/smjerovi/smjer[2]/vrstaZnanstvenoPodrucje != 1)">
                              <xsl:text>in the fields of </xsl:text>
                              <xsl:value-of select="lower-case(studijskiProgram/smjerovi/smjer[1]/nazZnanstvenoPodrucje)" />
                              <xsl:text> and </xsl:text>
                              <xsl:value-of select="lower-case(studijskiProgram/smjerovi/smjer[2]/nazZnanstvenoPodrucje)" />
                              <xsl:text> </xsl:text>
                        </xsl:when>

                        <xsl:when test="(studijskiProgram/smjerovi/smjer[1]/vrstaZnanstvenoPodrucje = 1) and (studijskiProgram/smjerovi/smjer[2]/vrstaZnanstvenoPodrucje != 1)">
                              <xsl:text>in the scientific field of </xsl:text>
                              <xsl:value-of select="lower-case(studijskiProgram/smjerovi/smjer[1]/nazZnanstvenoPodrucje)" />
                              <xsl:text> and in the field of </xsl:text>
                              <xsl:value-of select="lower-case(studijskiProgram/smjerovi/smjer[2]/nazZnanstvenoPodrucje)" />
                              <xsl:text> </xsl:text>
                        </xsl:when>

                        <xsl:when test="(studijskiProgram/smjerovi/smjer[1]/vrstaZnanstvenoPodrucje != 1) and (studijskiProgram/smjerovi/smjer[2]/vrstaZnanstvenoPodrucje = 1)">
                              <xsl:text>in the field of </xsl:text>
                              <xsl:value-of select="lower-case(studijskiProgram/smjerovi/smjer[1]/nazZnanstvenoPodrucje)" />
                              <xsl:text> and in the scientific field of </xsl:text>
                              <xsl:value-of select="lower-case(studijskiProgram/smjerovi/smjer[2]/nazZnanstvenoPodrucje)" />
                              <xsl:text> </xsl:text>
                        </xsl:when>

                     </xsl:choose>
                </xsl:otherwise>
            </xsl:choose>

         </xsl:when>
      </xsl:choose>

   </xsl:template>

Template poziv

Navedeni template se poziva na dva mjesta - u hrvatskom i engleskom dijelu predloška.

Na 489. liniji poziva se template u hrvatskom dijelu predloška:

                <xsl:call-template name="ispisZnanstvenoPodrucje">
                  <xsl:with-param name="lang" select="$lang"/>
                  <xsl:with-param name="spol" select="$spol"/>
               </xsl:call-template>


umjesto prethodno definiranog ispisa koji je izbačen na tom mjestu

Izbačeni ispis
               <xsl:value-of
                    select="document(concat('file:///', $konTekstDiploma))
                           /konTekst/jezik[lang($lang)]
                           /iStekao[contains(@spol,$spol)]" />
               <xsl:text> </xsl:text>


Na 531. liniji poziva se template u engleskom dijelu predloška:

               <xsl:text> </xsl:text>

               <xsl:call-template name="ispisZnanstvenoPodrucje">
                  <xsl:with-param name="lang" select="$lang"/>
                  <xsl:with-param name="spol" select="$spol"/>
               </xsl:call-template>



  • No labels